Форумы HiProg.com - MS ACCESS, VBA, VB

 

Ответить на сообщение

Вернуться к теме

Вы отвечаете на сообщение:

ник: Lukas
Как вариант:
1. Объявляем глобальную переменную в общем модуле:

Public glbIDProduct As Long

2. Из вызывающей формы, на клик кнопки справа от ComboBox "IDProduct"

Private Sub btnSelectProduct_Click()
On Error GoTo Err_btnSelectProduct_Click
    Me.IDProduct = funSelectProduct(Me.IDProduct)
    Me.IDProduct.Requery
Exit_btnSelectProduct_Click:
    Exit Sub

Err_btnSelectProduct_Click:
    MsgBox Err.Description, vbExclamation, Me.Caption
    Resume Exit_btnSelectProduct_Click
End Sub

3. Функция в общем модуле:

Public Function funSelectProduct(IDProduct As Variant) As Long
On Error GoTo Err_function

    Dim lngOpenArg As Long
    lngOpenArg = Nz(IDProduct, 0)
    DoCmd.OpenForm "frmListProduct", acNormal, , , , acDialog, lngOpenArg
    funSelectProduct = glbIDProduct
    
Exit_function:
    Exit Function

Err_function:
    MsgBox Err.Description, vbExclamation, "Функция Выбор продукции"
    Resume Exit_function
    
End Function

4. В форме-справочнике, используется в данном случае ListBox "ListProduct" для отображения и кнопка выбора "btnSelect":

Private Sub Form_Load()
    Me.ListProduct = Nz(Me.OpenArgs, Me.ListProduct.Column(0, 0))
End Sub

Private Sub btnSelect_Click()
On Error GoTo Err_btnSelect_Click
    If Nz(Me.ListProduct, 0) = 0 Then
        MsgBox "Продукция не выбрана!", vbExclamation, Me.Caption
        Exit Sub
    End If
    glbIDProduct = Nz(Me.ListProduct, 0)
    DoCmd.Close

Exit_btnSelect_Click:
    Exit Sub

Err_btnSelect_Click:
    MsgBox Err.Description, vbExclamation, Me.Caption
    Resume Exit_btnSelect_Click
    
End Sub


Ваше имя:

Пароль:
Цитировать: [quote][/quote] Код: [code][/code]
Жирный: [b][/b] Наклонный: [i][/i]
URL: [url][/url] 

Сообщение:

 Размер файла не более 50 Кбт. Большие файлы можно размещать на www.slil.ru

Прикрепить:

 

Для вставки смайлов в текст щелкните по значку.